8.3.1 Eventos de ratón ¶

El cursor del ratón entra en la zona de juego ¶

Queremos capturar los eventos cuando el cursor del ratón se mueve sobre nuestro morph SpaceWar.

Una vez que dejamos claro que queremos que el juego reciba eventos de desplazamiento del ratón, debemos configurar el comportamiento en consecuencia con métodos específicos.

Cada vez que el cursor del ratón entra en el juego, queremos:

• Obtener el foco del teclado. Sigue al cursor del ratón: la entrada del teclado va al morph situado bajo el cursor del ratón. En Cuis-Smalltalk, el cursor del ratón se modela como una instancia HandMorph, un objeto de evento (véase la jerarquía de clases de eventos al principio de este capítulo). Se pregunta a un objeto de evento por su manejo con el mensaje #hand. En definitiva, queremos que el foco del teclado se dirija hacia nuestro juego cuando entra el ratón:

  event hand newKeyboardFocus: self
  

• Reanudar el juego. La actualización continua del juego se realiza mediante un mecanismo de pasos dedicado, que se explicará en el siguiente capítulo. El juego solo tiene que solicitar la reanudación de los pasos:

  self startStepping
  

El cursor del ratón deja la zona de juego ¶

También queremos que se nos informe cuando el cursor del ratón abandone nuestro morph SpaceWar. Gracias al trabajo realizado en Ejercicio 8.1, ya hemos informado a Cuis-Smalltalk de que queremos que se nos notifique el movimiento del ratón sobre el juego. Sin embargo, necesitamos programar el comportamiento cuando el cursor del ratón abandona el juego:

• Liberar el foco del teclado. Le indicamos a Cuis-Smalltalk que el juego no quiere el foco del teclado:

  event hand releaseKeyboardFocus: self
  

• Pausar el juego. Detendremos la actualización (stepping) continua del juego:

  self stopStepping
  

En la interfaz gráfica de usuario, a menudo se utiliza un efecto visual para informar al usuario de que el foco del teclado ha cambiado. En Spacewar! cambiamos el fondo del juego en función del estado del foco del teclado.

En la Figura 8.1, a la izquierda el foco del teclado está en el juego; a la derecha el foco del teclado no está en el juego, está en pausa y podemos ver a través.

Figura 8.1: Efecto Spacewar! dependiendo del foco del teclado

En el marco Morph, el mensaje #keyboardFocusChange: se envía al morph que pierde o gana el foco del teclado, su parámetro es un booleano. Por lo tanto, implementamos el comportamiento Figura 8.1 en el método correspondiente keyboardFocusChange de SpaceWar:

SpaceWar>>keyboardFocusChange: gotFocus
   gotFocus 
      ifTrue: [color := self defaultColor]
      ifFalse: [color := self defaultColor alpha: 0.5].
   self redrawNeeded

8.3.2 Eventos de teclado ¶

Para controlar las naves espaciales, utilizamos el teclado. Por lo tanto, queremos que el juego sea notificado de los eventos del teclado.

Podemos decidir que se nos notifique el evento de pulsación o liberación de tecla, así como el evento de pulsación y liberación de tecla (pulso de tecla). Siempre que nuestro morph SpaceWar responda verdadero al mensaje #handlesKeyboard, recibirá los mensajes #keyUp:, #keyDown: y #keyStroke:. Por defecto, los métodos coincidentes de la clase Morph no hacen nada.

El argumento de estos mensajes es un objeto KeyboardEvent al que, entre otras cosas, se le puede preguntar el #keyCharacter de la tecla pulsada o comprobar algunas teclas especiales, como las flechas del teclado. La nave del primer jugador, –la verde–, se controla con las flechas del teclado cuando se pulsan:

SpaceWar>>keyStroke: event
   event isArrowUp ifTrue: [^ ships first push].
   event isArrowRight ifTrue: [^ ships first right].
   event isArrowLeft ifTrue: [^ ships first left].
   event isArrowDown ifTrue: [^ ships first fireTorpedo].
   ...

Para controlar la nave del segundo jugador, utilizamos otra disposición clásica en los juegos controlados con teclado QWERTY: WASD.²⁷.